puppet_agent.pp

# puppet agent auf cron umstellen
class ubuntu_server::puppet_agent($nightly_only=false,$on_reboot_once=true){

    $puppet_cron_time = fqdn_rand(28,'puppet_cron_time') + 1
    $puppet_cron_time_plus_30 = $puppet_cron_time + 30

    File{
        owner => root,
        group => root,
        mode => 0644,
    }

    if $nightly_only == true {
        $nightly_hours = '2-5/1'
    } else {
        $nightly_hours = '*'
    }

    file{'/etc/cron.d/puppet-cron':
        ensure  => present,
        content => template('ubuntu_server/etc/cron.d/puppet-cron.erb'),
    } -> Service['puppet']

    if $on_reboot_once == true {
        file{'/etc/cron.d/puppet-cron-reboot':
            ensure  => present,
            content => template('ubuntu_server/etc/cron.d/puppet-cron-reboot.erb'),
        } -> Service['puppet']
    }

    file{'/etc/rsyslog.d/31-puppet-agent.conf':
        ensure => present,
        source => 'puppet:///modules/ubuntu_server/etc/rsyslog.d/31-puppet-agent.conf',
    } ~> Service['rsyslog']

    file{'/etc/logrotate.d/puppet-agent':
        ensure => present,
        source => 'puppet:///modules/ubuntu_server/etc/logrotate.d/puppet-agent',
    }

    service{'rsyslog':
        ensure => running,
    }

    service{'puppet':
        ensure => stopped,
        enable => false,
    }

}